Программирование на Ассемблере
Затем поставьте контрольную точку на первую команду rts (для
этого нужно нажать , предварительно указав мышью на нужную
строку). Выполните программу, наблюдая за содержимым регистра D2. После
этого выберите пункт меню \"Parameter-Display-HEX-Dump\" и убедитесь, что
буфер действительно содержит строку \"4A\".
Обратите внимание на очередность обработки полубайтов: сначала мы
конвертируем старший полубайт, а затем младший (так как строки выводятся на
экран слева-направо). При этом мы выделяем буфер такого размера, чтобы туда
поместилось ASCII-представление длинного слова (8 символов), а за строкой
символов всегда следовал нулевой байт (это нужно для правильной работы
подпрограмм вывода строк на экран, но об этом позже). Теперь осталось
написать программу для преобразования длинных слов.
В случае длинных слов нам нужно обращать особое внимание на порядок
обработки полубайтов. Перед первым вызовом подпрограммы nibble самый
старший полубайт должен быть помещен на первое место, при этом никакие биты
не должны терятся.
Понятно, что команда LSR для этого не совсем подходит. Поэтому будем
использовать команды прокрутки ROR и ROL (напомним, что эти команды
гарантируют сохранение всех битов операнда).
Если мы прокрутим содержимое D1 влево на четыре бита, то старший полубайт
окажется на месте младшего и можно будет вызвать подпрограмму nibble.
Повторив те же действия еще семь раз, мы получим нужный результат, причем
регистр D1 вернется к своему первоначальному значению:
;(4.3.1B) bin-hex-2
hexlong:
lea buffer,A0 ;адрес буфера - в A0
move.l #$12345678,D1 ;число для преобразования
moveq #8-1,D3 ;счетчик полубайтов
loop:
rol #4,D1 ;старший полубайт - в начало
move D1,D2 ;данные для nibble
bsr.s nibble ;конвертируем полубайт
move.b D2,(A0)+ ;результат - в буфер
dbra D3,loop ;повторить 8 раз
rts ;и все!
nibble:
and #$0F,D2 ;оставляем младший полубайт
add #$30,D2 ;прибавляем $30
cmp #$3A,D2 ;цифра?
bcs.s ok ;да, код - в D2
addq #7,D2 ;иначе добавляем еще 7
ok: rts ;все
buffer:
blk.b 9,0 ;место для результата плюс один
;резервный нулевой байт
end
Оттранслируйте эту программу и загрузите в отладчик, затем поставьте
контрольную точку на первую команду возврата (rts) и запустите.
|
